Библиотека администрирования кластера серверов 1С

Библиотека управления кластером 1С

GitHub release GitHub license Build Status Quality Gate Coverage Tech debt

Назначение

Библиотека (oscript) irac предоставляет интерфейс управления кластером серверов 1С:Предприятие 8 с использованием утилиты администрирования кластера (RAC).

Принцип работы

Библиотека подключается, как отдельный класс и используется для вызова команд утилиты RAC для взаимодействия с одним экземпляром сервера администрирования кластера 1С.

Пример получения списка кластеров, параметров серверов и информационных баз

#Использовать irac
Админ = Новый Структура();
Админ.Вставить("Администратор", "admin");
Админ.Вставить("Пароль", "P@$$w0rd");

Админка = Новый УправлениеКластером1С("8.3", "localhost:1545", Админ);

Кластеры = Админка.Кластеры();

// Обходим список кластеров
Для Каждого Кластер Из Кластеры.Список() Цикл
    Сообщить(Кластер.Получить("Имя"));
КонецЦикла;

// Кластер.УстановитьАдминистратора("<admin>", "<pwd>"); // - указывается если задан администратор кластера

Серверы = Кластер.Серверы();

// Обходим список серверов
Для Каждого Сервер Из Серверы.Список() Цикл

    Сообщить(Сервер.Имя() + " (" + Сервер.АдресСервера() + ":" + Сервер.ПортСервера() + ")");

    Для Каждого ТекАтрибут Из Серверы.ПараметрыОбъекта().ОписаниеСвойств() Цикл
        Сообщить(ТекАтрибут.Ключ + " : " + Сервер.Получить(ТекАтрибут.Значение.Имя));
    КонецЦикла;

КонецЦикла;

ИБ = Кластер.ИнформационныеБазы();

Сообщить("Всего ИБ: " + ИБ.Список().Количество());

// Обходим список информационных баз
Для Каждого ТекИБ Из ИБ.Список() Цикл

    Сообщить(ТекИБ.Имя() + " (" + ?(ТекИБ.ПолноеОписание(), "Полное", "Сокращенное") + " " + ТекИБ.Описание() + ")");

    Для Каждого ТекАтрибут Из ИБ.ПараметрыОбъекта().ОписаниеСвойств() Цикл
        Сообщить(ТекАтрибут.Ключ + " : " + ТекИБ.Получить(ТекАтрибут.Значение.Имя));
    КонецЦикла;

КонецЦикла;

Пример блокировки/разблокировки сеансов в информационной базе


#Использовать irac

Админ = Новый Структура("Администратор, Пароль", "agentAdmin", "P@$$w0rd");
Управление = Новый УправлениеКластером1С("8.3", "localhost:1545", Админ);

Кластер = Управление.Кластеры().Список()[0];
Кластер.УстановитьАдминистратора("clusterAdmin", "P@$$w0rd");

// Получение ИБ по имени
ИБ = Кластер.ИнформационныеБазы().Получить("MyAwesomeDatabase");
ИБ.УстановитьАдминистратора("Администратор", "P@$$w0rd");

// Установка блокировки начала сеансов с базой
ПараметрыИБ = Новый Структура();
ПараметрыИБ.Вставить("НачалоБлокировкиСеансов"   , Дата(20010101));
ПараметрыИБ.Вставить("ОкончаниеБлокировкиСеансов", Дата(20991231));
ПараметрыИБ.Вставить("СообщениеБлокировкиСеансов", "База заблокирована до особых распоряжений");
ПараметрыИБ.Вставить("КодРазрешения"             , "SuperSecretKey");
ПараметрыИБ.Вставить("БлокировкаСеансовВключена" , Перечисления.СостоянияВыключателя.Включено);

ИБ.Изменить(ПараметрыИБ);

// Снятие блокировки начала сеансов с базой
ПараметрыИБ = Новый Структура();
ПараметрыИБ.Вставить("БлокировкаСеансовВключена" , Перечисления.СостоянияВыключателя.Выключено);

ИБ.Изменить(ПараметрыИБ);

Пример блокировки/разблокировки регламентных заданий в информационной базе


#Использовать irac

Админ = Новый Структура("Администратор, Пароль", "agentAdmin", "P@$$w0rd");
Управление = Новый УправлениеКластером1С("8.3", "localhost:1545", Админ);

Кластер.УстановитьАдминистратора("clusterAdmin", "P@$$w0rd");

// Получение ИБ по имени
ИБ = Кластер.ИнформационныеБазы().Получить("MyAwesomeDatabase");
ИБ.УстановитьАдминистратора("Администратор", "P@$$w0rd");

// Установка блокировки регламентных заданий
ПараметрыИБ = Новый Структура();
ПараметрыИБ.Вставить("БлокировкаРегламентныхЗаданийВключена" , Перечисления.СостоянияВыключателя.Включено);

ИБ.Изменить(ПараметрыИБ);
// Снятие блокировки регламентных заданий
ПараметрыИБ = Новый Структура();
ПараметрыИБ.Вставить("БлокировкаРегламентныхЗаданийВключена" , Перечисления.СостоянияВыключателя.Выключено);

ИБ.Изменить(ПараметрыИБ);

Структура основных объектов

УправлениеКластером1С

    |-Администраторы
    |-Кластеры
        |-Администраторы
        |-МенеджерыКластера
        |-Серверы
        |   |-ТребованияНазначения
        |-РабочиеПроцессы
        |   |-Лицензии
        |-ИнформационныеБазы
        |-Сервисы
        |-Сеансы
        |-Соединения
        |   |-Лицензии
        |-Блокировки
        |-ПрофилиБезопасности
        |-СчетчикиПотребленияРесурсов

Объекты и методы

УправлениеКластером1С

Основной класс библиотеки. Предоставляет интерфейс управления серверами 1С.

    УправлениеКластером = Новый УправлениеКластером1С("localhost", 1545, "8.3.10", "admin", "P@ssw0rd");
Параметры конструктора
АдресСервера Строка имя сервера агента администрирования (RAS)
ПортСервера Число порт сервера агента администрирования (RAS)
ВерсияИлиПутьКРАК Строка маска версии 1С или путь к утилите RAC
Администратор Строка администратор агента сервера 1С
ПарольАдминистратора Строка пароль администратора агента сервера 1С
Методы
СтрокаПодключения() Строка возвращает строку параметров подключения к агенту администрирования (RAS)
СтрокаАвторизации() Строка возвращает строку параметров авторизации на агенте кластера 1С
УстановитьАдминистратора(Администратор, Пароль) устанавливает параметры авторизации на агенте кластера 1С
ИсполнительКоманд() ИсполнительКоманд возвращает текущий объект-исполнитель команд
УстановитьИсполнительКоманд(НовыйИсполнитель) устанавливает объект-исполнитель команд
ОписаниеПодключения() Строка возвращает строку описания подключения к серверу администрирования кластера 1С
Администраторы() АдминистраторыАгента возвращает список администраторов агента кластера 1С
Кластеры() Кластеры возвращает список кластеров 1С
ВыполнитьКоманду(ПараметрыКоманды) Число передает команду в объект-исполнитель команды и возвращает код возврата команды
ВыводКоманды() Массив(Соответствие) возвращает вывод команды из объекта-исполнитель команд

ИсполнительКоманд

Вспомогательный объект для выполнения команд. Непосредственно вызывает утилиту RAC.

    УправлениеКластером = Новый УправлениеКластером1С("localhost", 1545, "8.3.10", "admin", "P@ssw0rd");
    УправлениеКластером.УстановитьИсполнительКоманд(Новый ИсполнительКоманд("8.3"));
Параметры конструктора
ВерсияИлиПутьКРАК Строка маска версии 1С или путь к утилите RAC
Методы
ВерсияУтилитыАдминистрирования() Строка возвращает версию утилиты RAC
ПутьКУтилитеАдминистрирования() Строка возвращает путь к утилите RAC
УстановитьПутьКУтилитеАдминистрирования(Путь) устанавливает переданный путь к утилите RAC
ВыполнитьКоманду(ПараметрыКоманды) Массив(Соответствие) выполняет команду и возвращает код возврата
ВыводКоманды(РазобратьВывод) Строка/Массив(Соответствие) возвращает вывод команды
КодВозврата() Число возвращает код возврата выполнения команды

Кластеры

Объект предоставляет доступ к списку кластеров, доступных для администрирования.

    УправлениеКластером = Новый УправлениеКластером1С("localhost", 1545, "8.3.10", "admin", "P@ssw0rd");
    СписокКластеров = Новый Кластеры(УправлениеКластером);
    УправлениеКластером = Новый УправлениеКластером1С("localhost", 1545, "8.3.10", "admin", "P@ssw0rd");
    СписокКластеров = УправлениеКластером.Кластеры();
Параметры конструктора
АгентКластера УправлениеКластером1С ссылка на родительский объект агент кластера
Методы
ОбновитьДанные(РежимОбновления) обновляет список кластеров вызывая утилиту RAC
ПараметрыОбъекта() Соответствие список параметров объекта кластера
Список(Отбор, РежимОбновления) возвращает список кластеров, соответствующих отбору
ВыполнитьКоманду(ПараметрыКоманды) Массив(Соответствие) выполняет команду и возвращает код возврата
ВыводКоманды(РазобратьВывод) Строка/Массив(Соответствие) возвращает вывод команды
КодВозврата() Число возвращает код возврата выполнения команды

Доступные версии пакета

1.3.0
Изменен: 17.06.2022 12:15:22
1.2.2
Изменен: 27.04.2022 10:08:40
1.2.1
Изменен: 15.04.2022 08:59:36
1.2.0
Изменен: 27.10.2021 08:34:32
1.1.2
Изменен: 09.09.2021 17:22:10
1.1.1
Изменен: 31.08.2021 14:15:47
1.1.0
Изменен: 16.07.2021 16:28:33
1.0.1
Изменен: 03.04.2021 19:19:41
1.0.0
Изменен: 18.02.2021 18:36:39
0.14.0
Изменен: 30.05.2020 12:13:07
0.13.0
Изменен: 15.01.2020 05:21:53
0.12.0
Изменен: 18.10.2019 15:06:58
0.11.1
Изменен: 13.10.2019 12:20:59
0.11.0
Изменен: 10.10.2019 14:15:27
0.10.0
Изменен: 27.09.2019 15:46:46
0.9.3
Изменен: 26.09.2019 13:56:44
0.9.2
Изменен: 25.09.2019 14:55:09
0.9.1
Изменен: 24.09.2019 08:39:10
0.9.0
Изменен: 23.09.2019 08:39:35
0.8.1
Изменен: 20.05.2019 11:31:08
0.8.0
Изменен: 02.01.2019 19:48:29
0.7.0
Изменен: 02.01.2019 19:48:29
0.6.0
Изменен: 02.01.2019 19:48:29
0.5.0
Изменен: 02.01.2019 19:48:29
0.4.0
Изменен: 02.01.2019 19:48:29
0.3.1
Изменен: 02.01.2019 19:48:29
0.3.0
Изменен: 02.01.2019 19:48:29
В разработке

Репозиторий

https://github.com/oscript-library/irac

Актуальная версия

irac-1.3.0